Robotframework

Historiquement la première et seule bibliothèque de RFW, elle accueille un certain nombre de Keywords génériques divers et variés. Si dans les autres bibliothèques vous pensez qu'un Keyword est manquant, consultez cette bibliothèque, car il se peut que pour des raisons de rétrocompatibilité, le keyword n'ait pas été déplacé.

Cette bibliothèque vise à mettre à disposition des keywords pour la création et la manipulation de listes et de dictionnaires Python. À noter qu'historiquement, c'était la bibliothèque Built-in qui accueillait ce rôle. Aussi, dans un souci de rétrocompatibilité, certains Keywords sont toujours dans la bibliothèque Built-In.

Cette bibliothèque met à votre disposition des outils afin d'effectuer du multiprocess basique.

Cette bibliothèque permet de manipuler les chaînes de caractères et d'effectuer des tests sur ces dernières.

Cette bibliothèque n'a qu'un seul but : fournir les keywords nécessaires pour effectuer des screenshots.

Cette bibliothèque vous permettra d'interagir avec l'OS. Par exemple, la création de dossiers/fichiers, tester leurs existences…

Il s'agit d'une bibliothèque qui vous permettra d'établir des connexions Telnet vers vos serveurs.

Elle met à votre disposition des moyens d'interagir avec l'utilisateur.

Selenium est une bibliothèque RFW tierce permettant de manipuler les sites web. Il existe SeleniumLibrary et Selenium2Library. C'est cette dernière qu'il faut désormais utiliser. Elle utilise un webdriver afin de piloter les différents navigateurs.

La bibliothèque Selenium étant développée sous Firefox, c'est sous ce navigateur que la compatibilité est maximale.

Cette bibliothèque tierce vous permettra de manipuler des applications MS Windows sous réserve qu'elles n'utilisent pas des technologies trop récentes. À titre d'exemple, MS Office n'est pas manipulable, mais un installeur Inno Setup l'est.

À titre d'information, il existe une bibliothèque s'appelant Pywinauto, 100 % Python, permettant de faire la même chose.

Cette bibliothèque tierce vous permettra d'effectuer des tâches via SSH, et ainsi de manipuler une machine distante. Très pratique en environnement Unix.

DataBase Library Python est une bibliothèque tierce RFW qui vous permettra de manipuler un certain nombre de BDD afin d'y effectuer diverses opérations.

Cette bibliothèque tierce vous permettra d'effectuer des tâches FTP en simulant un client FTP.

Cette bibliothèque tierce vous permettra de comparer deux fichiers texte simplement.

Il s'agit de l'IDE officiel de RFW. Assez complet, même si d'aspect simpliste, il nécessite l'installation de wxwidget.

Il vous permettra de lancer directement vos tests sans passer par la ligne de commande.

C'est la seconde solution, et la plus répandue. Nombreux sont les IDE génériques à disposer de plugin RFW. Selon la qualité de ces plugins, vous pourrez également lancer les tests depuis votre IDE ou encore récupérer les logs de résultats.

Je vous invite également à regarder du côté de « pygments » qui vous permettra de disposer d'une préconfiguration RFW pour la coloration syntaxique de votre code.

Pour lancer un test, le mieux reste donc, comme précisé plus tôt, d'utiliser directement la ligne de commande.

Aussi, après vous être assuré que la commande « pybot » était bien reconnue par votre système (cas échéant, avisez), exécutez la commande suivante :

pybot <chemin vers votre fichier txt>

Votre test se lance alors. Trois fichiers seront alors d'office générés :

• output.xml ;
• log.html ;
• report.html.

Cependant, vous pourriez vouloir « personnaliser » un peu le paramétrage de cette commande. Cela est tout à fait possible.

En effet la commande « pybot » dispose de nombreuses options. Nous allons voir ici les plus usuelles. Pour les restantes, je vous invite à vous plonger plus longuement dans la documentation RobotFramework.

En ligne de commande, les messages renvoyés sont particulièrement pauvres et se limitent au strict minimum. Aussi la plupart du temps les messages sont-ils à peine suffisants pour déboguer.

Avec RIDE, les choses s'améliorent un peu. En effet, l'IDE RFW essaie de mettre un peu plus en évidence les zones de l'erreur, ainsi que la cause, même si cela n'est pas toujours très explicite.

Généré systématiquement, que RFW ait été lancé via une ligne de commande ou via RIDE, le fichier HTML est réellement indispensable.

Il contient en effet tout ce qui se passe au cours des tests : les différentes valeurs d'une variable, retour de keywords, capture d'écran, log de dictionnaire…

Cet outil utilise également une coloration syntaxique afin de différencier les étapes se déroulant normalement, des autres.

Enfin, par défaut, seules les étapes en échec seront affichées, optimisant ainsi l'interprétation des fichiers de résultats de tests.

Les seules ressources internes importables sont les bibliothèques vues précédemment (Built-in, Telnet…). On utilise le mot clé « Library » pour les importer :

*** Settings ***
Library    BuiltIn

Dans le cas d'une bibliothèque maison, par exemple la classe MyLib dans le fichier myproject.py dont le chemin d'accès serait com.mycompany.myproject, il faudra utiliser la notation suivante :

*** Settings ***
Library    com.mycompany.myproject.MyLib        WITH NAME    MyLib

Plus loin dans le code nous pourrons accéder aux différents keywords ainsi :

*** Keywords ***
My Keyword
    MyLib.Mon Keyword        argument

Dans le cas d'un fichier de ressources, généralement des variables prédéfinies, on utilisera le mot clé « Variables » :

*** Settings ***
Variables    mon_fichier.py

La notation RFW pour une variable est « ${nom_de_la_variable} ».

Par convention, le nom des variables sera constitué de minuscules, avec des underscores.

*** Variables ***
${message}        Hello, world!
${entier_42}      ${42}

Les fichiers de variables ne sont rien de plus qu'un fichier à l'extension « .py » contenant des variables de type Python.

# -*- Coding: utf-8 -*- 

var01 = "Hello " 
var02 = "world!"

Et dans le fichier RFW :

*** Settings *** 
Variables        myvars.py 

*** Test Cases *** 
Test01 
    My Keyword 

*** Keywords *** 
My Keyword 
    Log        ${var01} ${var02}

La définition d'une variable globale se fait en deux temps. Tout d'abord la variable doit être définie dans la section « Variable » ou bien importée depuis un fichier de variables.

Ensuite, juste avant de quitter un espace de noms (un test case ou un keyword, dans RFW), il faut utiliser le keyword « Set Global Variable ».

*** Variables ***
${var}        3

*** Test Cases ***
Test01
    Log    ${var}
    My Keyword
    Log    ${var}

*** Keywords ***
My Keyword
    ${var} =    Set Variable    5
    Set Global Variable    ${var}

Si vous exécutez ce code, vous verrez qu'avant l'appel du keyword, « var » vaut 3, et qu'après il vaut 5. Supprimez maintenant le « Set Global Variable » (ou mettez la ligne en commentaire avec « # »), et relancez le test.

Maintenant, « var » vaut toujours 3. Nous retombons en fait dans l'équivalent des espaces de noms en Python.

Il existe un certain nombre de variables fournies et préconfigurées par défaut. Voici les plus usuelles.

Ces variables s'utilisent comme n'importe quelle variable que vous auriez vous-même définie.

Les listes et les dictionnaires se créent via des keywords dédiés. Nous allons voir ici deux exemples de création :

*** Settings *** 
Library     BuiltIn 
Library        Collections 
 
*** Test Cases *** 
CreationListe 
    ${list} =    Create List        a    b    c    d 
    Log        ${list} 
    ${tmp} =    Get From List    ${list}        0 
    Log        ${tmp} 

CreationDict 
    ${dict} =    Create Dictionary    a    1    b    2 
    Log        ${dict} 
    ${tmp} =    Get From Dictionary        ${dict}        a     
    Log        ${tmp}

Vous remarquerez ici que l'on ne peut logger directement un extract de liste ou de dictionnaire. Il faut obligatoirement passer par une variable temporaire. Il en est de même avec le [Return] des keywords.

Je vais ici vous dresser la liste des keywords les plus utiles, et vous les décrire rapidement. Pour de plus amples informations, notamment leur usage, je vous renvoie vers les documentations officielles. Je ne peux que vous inviter à les lire en entier pour vous en imprégner.

Ce que nous appellerons des keywords personnalisés désignent en fait ceux que nous écrirons dans la section « Keywords » qui sera présentée plus loin.

*** Settings *** 
Library        BuiltIn 

*** Test Cases *** 
Cas1 
    ${result}=        Mon Keyword        2 

*** Keywords *** 
Mon Keyword 
    [Arguments]        ${arg1} 
    Log        ${arg1} 
    ${tmp}=        Evaluate    int('${arg1}') * 2 
    [return]    ${tmp}

Dans cet exemple, nous pouvons voir l'usage de certaines options décrites ci-après.

Ce que nous noterons ici, est la façon dont on utilise les variables dans du code Python. N'oublions pas en effet que RobotFramework traite les variables comme des chaînes de caractères.

Nous pouvons également voir comment utiliser les keywords personnalisés.

Il existe un certain nombre d'options pour les keywords. Ces options s'écrivent entre crochets, et sont suivies de leurs arguments.

Les boucles FOR sont un peu particulières en RFW. Leur utilisation est proche du FOR Python, mais elles sont peu pratiques à coder. Cependant, cela peut s'avérer utile dans certains cas.

*** Settings ***
Library     BuiltIn
Library        Collections

*** Test Cases ***
TestCase01
    My Keyword 01
    My Keyword 02

*** Keywords ***
My Keyword 01
    :FOR    ${animal}    IN    chat    chien
    \        Log        ${animal}
    \        Log        Animal enregistre

My Keyword 02
    ${ma_liste} =    Create List        chat    chien
    :FOR    ${item}        IN        @{ma_liste}
    \        Log        ${item}

Comme on peut le voir dans « My Keyword 02 », il faut remplacer « $ » par « @ » lorsqu'on parcourt une liste avec une boucle FOR.

Je vous invite à laisser le « $ » afin de constater ce que cela vous renvoie.

À l'instar de Python, sur lequel il se base, RFW dispose également d'un FOR… IN RANGE.

*** Settings *** 
Library     BuiltIn 

*** Test Cases *** 
TestCase01 
    My Keyword 01 

*** Keywords *** 
My Keyword 01 
    :FOR    ${number}    IN RANGE    2    9    3 
    \        Log        ${number}

Comme nous pouvons le voir dans cet exemple, le fonctionnement est identique à Python : start, stop, step.

Vous pouvez quitter une boucle avec le keyword « Exit For Loop ».

Il existe plusieurs keywords associés au IF. La plupart correspondent à un prédicat prédéfini (Continue For Loop If, Set Variable If…). Je vous renvoie vers la documentation de la bibliothèque Built-In pour en prendre connaissance.

Le keyword équivalent à un IF Python est « Run Keyword If ». Comme le laisse suggérer ce keyword, nous n'allons pas exécuter un code, mais appeler un Keyword, lequel contiendra le code que nous désirons exécuter.

*** Settings ***
Library     BuiltIn

*** Test Cases ***
TestCase01
    My Keyword 01

*** Keywords ***
My Keyword 01
    :FOR    ${number}    IN RANGE    2    12    3
    \        Log        ${number}
    \        Run Keyword If        '${number}' == '8'        Exit For Loop

Bien qu'il existe la possibilité de faire un ELSE ou encore un ELSE IF, je vous recommanderais plutôt de faire plusieurs Run Keyword If, qui à l'usage se révèlent moins capricieux.

On peut définir certaines options sur les test cases. Voici les principaux :

MyTestCase
    [Documentation]    Voici comment documenter un test case
    [Tags]    demo
    [Arguments]        Arg1        Arg2="hello"
    Log    Arg1
    Log    Arg2

Tout comme pour les test cases, on peut définir des options pour les test suites. Cependant, un test suite pouvant prendre différentes formes (fichier ou dossier), la façon de faire peut varier.

Dans le cas d'un dossier, cela est fort simple, puisqu'il s'agit alors de créer un fichier __init__.txt, puis d'y entrer tout ou partie des options suivantes :

[Documentation]    Documentation du test suite
[Suite Setup]    Setup Du Test Suite
[Test Timeout]    60s

Si le test suite consiste en un fichier, on peut utiliser les mêmes options, mais celles-ci seront à déclarer en début de fichier dans la section Settings (voir plus loin).

L'écriture de tests en mode verbeux correspond aux exemples vus jusqu'ici. Il s'agit donc d'un simple fichier texte, découpé en quatre sections, et utilisant comme caractère de séparation la tabulation.

Il n'existe pas vraiment de mode Python pour écrire des tests. Ce que l'on fait en vérité, c'est écrire des bibliothèques, et simplement y faire appel depuis un fichier RFW en mode verbeux.

Je vous renvoie donc vers la section bibliothèques Python, ci-après pour savoir comment faire.

Écrire une bibliothèque en mode verbeux n'est pas compliqué en soi. En fait, une bibliothèque RFW n'est rien d'autre qu'un fichier test RFW que l'on peut importer dans un autre fichier de test RFW.

*** Settings *** 
Library     BuiltIn 

*** Keywords *** 
My External Keyword 
    Log        Je log ici depuis un keyword importé

*** Settings *** 
Library     BuiltIn 
Resource    ma_lib.txt 

*** Test Cases *** 
TestCase01 
    My Keyword 01 
    My External Keyword 

*** Keywords *** 
My Keyword 01 
    :FOR    ${number}    IN RANGE    2    12    3 
    \        Log        ${number} 
    \        Run Keyword If        '${number}' == '8'        Exit For Loop

L'écriture d'une bibliothèque RFW repose sur des concepts basiques de Python. Il y aura cependant quelques subtilités que nous allons voir ici.

Pour commencer, le point d'entrée côté RFW s'effectuera au niveau d'une classe. Vos bibliothèques en contiendront donc toujours. Les méthodes de ces classes constitueront les keywords.

Le nom des méthodes s'écrira en minuscules et avec des underscores, côté Python. Une fois importés côté RFW, les différents mots seront capitalisés et les underscores remplacés par un simple espace.

Si un nom de méthode commence par un underscore, il sera considéré comme privé, et donc non accessible depuis RFW.

Côté paramètres, à moins que vous n'ayez créé un élément spécifique (liste, dictionnaire) ou ayez utilisé la notation spécifique entier (rappel : ${mon_entier}), tout paramètre sera passé en tant que chaîne de caractères.

De manière similaire à Python, vous pouvez utiliser *args et **kwargs.

Si l'on désire logger quelque chose dans le fichier de sortie, il suffit d'effectuer un simple print.

Fichier 1 :

# -*- Coding: utf-8 -*-

__all__ = ['MaClass']

class MaClass:

    def __init__(self):
        pass

    def mon_keyword_perso(self, texte):
        print "voici comment imprimer dans le log.html"
        return "le texte etait: %s" % (texte)

Fichier 2 :

*** Settings ***
Library           BuiltIn
Library           ma_lib_python.MaClass

*** Test Cases ***
TestCase01
    My Keyword 01
    My Keyword 02

*** Keywords ***
My Keyword 01
    : FOR    ${number}    IN RANGE    2    12    3
    \    Log    ${number}
    \    Run Keyword If    '${number}' == '8'    Exit For Loop

My Keyword 02
    ma_lib_python.MaClass.Mon Keyword Perso    Hello, world!